*Create and view distributions;
DATA rand;
	do i=1 to 10000;
		* generate random values for 10000 observations;
		trt="trt";
		mynormal=rand("NORMAL", 85, 40);
		mylognormal=rand("LOGNORMAL", 1, 0.1);
		mybeta=rand("BETA", 1,99);
		mybinary=rand("BINOM", 0.95, 1);
		mybinomial=rand("BINOM", 0.95, 2000);
		myexponential=rand("EXPONENTIAL", 4.2);
		mygamma=rand("GAMMA", 2, 2);
		mygeometric=rand("GEOMETRIC", 0.10);
		mynegbinomial=rand("NEGBINOMIAL", 0.97, 1000);
		mypoisson=rand("POISSON", 10);
		output;
	end;

PROC PRINT data=rand(obs=20);

PROC UNIVARIATE data=rand;
	var mynormal mylognormal mybeta mybinary mybinomial myexponential mygamma mygeometric 
		mynegbinomial mypoisson;
	histogram;
	
	*can change around the parameters;
*----------------------------------------------------------------------------------------------------------------------------;

*Examples of distributions in action;

	*Datasets;
DATA Fish; set sashelp.Fish;
PROC PRINT data=Fish(obs=25);

DATA Baseball; set sashelp.Baseball;
PROC PRINT data=Baseball(obs=25);

	
	*Normal;
PROC UNIVARIATE data=Fish;
	where Species in ("Bream");
	var Length2;
	histogram/normal;
PROC GLIMMIX data=Fish;
	where Species in ("Bream");
	model Length2=Height/solution dist=Gaussian;

	*Log Normal;
PROC UNIVARIATE data=Fish;
	where Species in ("Bream");
	var Weight;
	histogram/normal lognormal;
DATA Fish; set Fish;
	ln_Weight=log(Weight);
PROC UNIVARIATE data=Fish;
	where Species in ("Bream");
	var ln_Weight;
	histogram/normal;	
PROC GLIMMIX data=Fish;
	where Species in ("Bream");
	model ln_Weight=Height/solution dist=Gaussian;	
PROC GLIMMIX data=Fish;
	where Species in ("Bream");
	model Weight=Height/solution dist=Lognormal;		

	*Exponential and Gamma;
PROC UNIVARIATE data=Baseball;
	var Salary;
	histogram/normal exponential gamma;	
PROC GLIMMIX data=Baseball;
	model Salary=CrRuns/s distribution=Exponential;
PROC GLIMMIX data=Baseball;
	model Salary=CrRuns/s distribution=Gamma;

	*Beta;
DATA Baseball; set Baseball;
	pHits=nHits/nAtBat;
PROC UNIVARIATE data=Baseball;
	var pHits;
	histogram/normal beta;	
PROC GLIMMIX data=Baseball;
	class Div;
	model pHits=Div/solution dist=Gaussian;
PROC GLIMMIX data=Baseball;
	class Div;
	model pHits=Div/solution dist=Beta;

	*Binary;
PROC GLIMMIX data=Baseball;
	model League(Event="American")=YrMajor/solution dist=binary;

	*Binomial;
DATA Baseball; set Baseball;
	nTotal=nHome+nRuns;
PROC GLIMMIX data=Baseball plots=all;
	class Div;
	model nHome/nTotal=Div/solution dist=Binomial;

	*Geometric;
PROC UNIVARIATE data=Baseball;
	var nHome;
	histogram;
PROC GLIMMIX data=Baseball;
	model nHome=Salary/solution dist=Geometric;
	
	*Poisson and Negative Binomial;
PROC GLIMMIX data=Baseball;
	model nHome=Salary/solution dist=Poisson;
PROC GLIMMIX data=Baseball;
	model nHome=Salary/solution dist=Negbinomial;